FX

package photoflockr;

import javafx.io.http.HttpRequest;
import javafx.data.pull.Event;
import javafx.data.pull.PullParser;
import javafx.data.xml.QName;
import java.util.Map;

def apiKey: String = "c8e56e2c73b31a14061f0981baa23a2a";

/**
 * This class is used to initiate HTTP requests to fetch pictures from the Flickr.
 * Requests are made on typing in the tag search field.
 */
public class Model {
    public var maxCount: Integer;
    public var tagMap: Map;
    public var queryString: String = "Flower" on replace { search(); }
    public var photos: PhotoModel[] = for (i in [1..maxCount]) PhotoModel {};

    // Every request is counted. The counter is used to detect if a subsequent
    // request is made. In such a case the previos request processing is interrupted.
    var queryCount: Integer = 0;

    // The function is called on typing in the tag search field (see Main.fx).
    function search(): Void {
        if (queryString == null or queryString.trim().length() == 0) {
            return;
        }
        tagMap.clear();
        PhotoRequest {
            tag: queryString
            queryNum: ++queryCount
        }.enqueue();
    }
}

/**
 * Parses XML data and retrieves URLs of a small and a large image
 * for every fetched picture.
 */
class PhotoParser extends PullParser {
    public-init var queryNum: Integer;

    var photoNum = 0;

    public override var onEvent = function(event: Event) {
        if (queryNum != Main.flockr.model.queryCount) {
            input.close();
            return;
        }
        if (event.type == PullParser.END_ELEMENT and
            event.level == 2 and
            event.qname.name == "photo" and
            photoNum < Main.flockr.BOID_COUNT)
        {
            def id = event.getAttributeValue(QName {name: "id"});
            def secret = event.getAttributeValue(QName {name: "secret"});
            def server = event.getAttributeValue(QName {name: "server"});
            def farm = event.getAttributeValue(QName {name: "farm"});

            Main.flockr.model.photos[photoNum] = PhotoModel {
                thumbUrl: "http://farm{farm}.static.flickr.com/{server}/{id}_{secret}_s.jpg"
                photoUrl: "http://farm{farm}.static.flickr.com/{server}/{id}_{secret}.jpg"
                tags: null // will be set later
            };

            TagRequest {
                photoID: id
                photo: Main.flockr.model.photos[photoNum++]
                queryNum: queryNum
            }.enqueue();
        }
    }
}

/**
 * Parses XML data and retieves the tag list for every fetched picture.
 */
class TagParser extends PullParser {
    public-read var tags: String[];
    public-init var queryNum: Integer;
    
    def TAG_MAX_COUNT = 30;
    var tagNum = 0;

    public override var onEvent = function(event: Event) {
        if (queryNum != Main.flockr.model.queryCount) {
            input.close();
            return;
        }
        if (event.type == PullParser.END_ELEMENT and
            event.level == 3 and
            event.qname.name == "tag" and
            tagNum++ < TAG_MAX_COUNT)
        {
            insert (event.text as String).trim() into tags;
        }
    }
}

/**
 * Performs an HTTP request for fetching photos XML data.
 */
class PhotoRequest extends HttpRequest {
    public-init var tag: String on replace {
        location = "http://api.flickr.com/services/rest/?method=flickr.photos.search&api_key={apiKey}&tags={tag}&per_page=15&page=1";
    }
    public-init var queryNum: Integer;

    override var method = HttpRequest.GET;

    public override var onInput = function(input: java.io.InputStream) {
        try {
            if (queryNum == Main.flockr.model.queryCount) {
                PhotoParser {
                    input: input
                    queryNum: queryNum
                }.parse();
            }
        } finally {
            input.close();
        }
    }
}

/**
 * Performs an HTTP request for fetching tags XML data.
 */
class TagRequest extends HttpRequest {
    public-init var photoID: String on replace {
        location = "http://api.flickr.com/services/rest/?method=flickr.tags.getListPhoto&api_key={apiKey}&photo_id={photoID}";
    }
    public-init var photo: PhotoModel;
    public-init var queryNum: Integer;

    override var method = HttpRequest.GET;

    public override var onInput = function(input: java.io.InputStream) {
        try {
            if (queryNum == Main.flockr.model.queryCount) {
                var parser = TagParser {
                    input: input
                    queryNum: queryNum
                }
                parser.parse();
                photo.tags = parser.tags;
            }
        } finally {
            input.close();
        }
    }
}